一个很实用的基于XML的网络mp3播放器

<?xml version="1.0" ?>
<songList>
<songs>
<songUrl><![CDATA[music/lwen.mp3]]></songUrl>
<songName><![CDATA[山歌年年唱春光]]></songName>
</songs>
<songs>
<songUrl><![CDATA[music/lwen2.mp3]]></songUrl>
<songName><![CDATA[山歌年年唱春光2]]></songName>
</songs>
</songList>

//这里只列两首

soundstop = 0;
//默认音乐为播放，只为关闭音乐时使用
//--------------------
createEmptyMovieClip("songMc", 50);
//建立一个空的MC存放mp3的信息（用数组也可以，但觉得没这方便）
createTextField("song_txt", 10, 30, 3, 300, 50);
//this.createTextField(instanceName, depth, x, y, width, height)
//建立一个动态文本框来显示歌曲名等
setSongtxt = function (string) {
   song_txt._width = Number(string.length*13);
   song_txt.text = string;
   // 以下几行是自定义文字的颜色等属性
   // myformat = new TextFormat();
   // myformat.font = sans;
   // myformat.color = 0xFFFF99;
   // myformat.align = right;
   // song_txt.setTextFormat(myformat);
};
//定义的控制动态文本框显示的内容及属性
//以下是处理xml里保存的mp3信息最好不要动，------------------------
xmlObj = new XML();
system.useCodepage = true;
xmlObj.ignoreWhite = true;
xmlObj.onLoad = function(success) {
   if (success) {
      setSongtxt("歌曲列表下载完毕");
      var i = 0;
      var one_xml = xmlObj.firstChild.firstChild;
      while (one_xml != null) {
         duplicateMovieClip("songMc", "songMc"+i, 100+i);
         var tempMc = eval("songMc"+i);
         var two_xml = one_xml.firstChild;
         while (two_xml.firstChild != null) {
            var a = two_xml.nodeName;
            tempMc[a] = two_xml.firstChild.nodeValue;
            //trace(a+" : "+tempMc[a]);
            // 看看输出的是什么就知道是怎么回事了
            two_xml = two_xml.nextSibling;
         }
         i++;
         one_xml = one_xml.nextSibling;
      }
      xmlLoad = 1;
      totalSongNum = i;
      //记下歌曲总数
      curNum = random(totalSongNum);
      // 随机选中一首
      //如果不喜欢老从第一首歌开始播放
      curSong(curNum);
      //调用播放的函数开始播放
   } else {
      setSongtxt("歌曲列表下载错误");
   }
};
//--------------
if (xmlLoad == undefined) {
   setSongtxt("下载歌曲列表");
   xmlObj.load("songlist.xml");
}
//---------------
my_sound = new Sound();
my_sound.onLoad = function(success) {
   if (success) {
      //如果下载成功。。。
      setSongtxt(curSongName);
      my_sound.setVolume(80);
      stop();
   } else {
      //如果下载失败。。。
      setSongtxt("歌曲下载错误");
      if (curNum<(totalSongNum-1)) {
         curNum++;
      } else {
         curNum = 0;
      }
      con = true;
   }
};
// select--------------
curSong = function (curNum) {
   var tempSong = eval("this.songMc"+curNum);
   curSongUrl = tempSong.songUrl;
   curSongName = tempSong.songName;
   // songUrl、songName分别与songlist.xml里对应
   my_sound.loadSound(curSongUrl, true);
   // 获取地址后加载音乐
};
// 一首歌结束时调用-----------------
my_sound.onSoundComplete = function() {
   if (curNum<(totalSongNum-1)) {
      curNum++;
   } else {
      curNum = 0;
   }
   con = true;
   play();
};
// -------------
if (con) {
   con = false;
   curSong(curNum);
}
//以下是按钮控制-----------
ctrl.stop_mc.onPress = function() {
   if (soundstop == 0) {
      soundstop = 1;
      my_sound.stop();
      ctrl.stop_mc.stop();
      setSongtxt("音乐已关闭");
   } else {
      soundstop = 0;
      my_sound.start();
      ctrl.stop_mc.play();
      setSongtxt(curSongName);
   }
};
ctrl.next_btn.onPress = function() {
   if (curNum<(totalSongNum-1)) {
      curNum++;
   } else {
      curNum = 0;
   }
   ctrl.stop_mc.play();
   con = true;
   play();
};
//END